FS/bin/freeside-censustract-update

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use Getopt::Std;
   5 use Date::Parse 'str2time';
   6 use FS::UID qw(adminsuidsetup);
   7 use FS::Record qw(qsearch dbh);
   8 use FS::Conf;
   9 use FS::cust_location;
  10 use FS::h_cust_location;
  11
  12 my %opt;
  13 getopts('d:', \%opt);
  14
  15 my $user = shift or die &usage;
  16 adminsuidsetup($user);
  17 $FS::UID::AutoCommit = 0;
  18 my $dbh = dbh;
  19
  20 my $conf = FS::Conf->new;
  21 my $current_year = $conf->config('census_legacy') || '2020';
  22 my $date = str2time($opt{d}) if $opt{d};
  23 $date ||= time;
  24 # This now operates on cust_location, not cust_main.
  25 # Find all locations that, as of $date, did not have
  26 # censusyear = the current year.  This includes those
  27 # that have no censusyear.
  28 my %h_cust_location = map { $_->locationnum => $_ }
  29   qsearch(
  30     'h_cust_location',
  31     { censusyear => { op => '!=', value => $current_year } },
  32     FS::h_cust_location->sql_h_search($date),
  33   ) ;
  34
  35 # Find all locations that don't have censusyear = the current
  36 # year as of now.
  37 my @cust_location = qsearch({
  38      'table'     => 'cust_location',
  39      'hashref'   => { 'country' => 'US', },
  40      'extra_sql' => " AND (    censusyear  != '$current_year'
  41                             OR censustract IS NULL
  42                           )
  43                     ",
  44 });
  45
  46 warn scalar(@cust_location)." records found.\n";
  47 my $queued = 0; my $updated = 0;
  48 foreach my $cust_location (@cust_location) {
  49   my $error;
  50   my $h = $h_cust_location{$cust_location->locationnum};
  51   if ( defined($h) and $h->censustract eq $cust_location->censustract ) {
  52     # Then the location's censustract hasn't been changed since $date
  53     # (or it didn't exist on $date, or $date is now).  Queue a censustract
  54     # update for it.
  55     my $job = FS::queue->new({
  56         job => 'FS::cust_location::process_censustract_update'
  57     });
  58     $error = $job->insert($cust_location->locationnum);
  59     $queued++;
  60   }
  61   elsif ($cust_location->censusyear eq '') {
  62     # Then it's been updated since $date, but somehow has a null censusyear.
  63     # (Is this still relevant?)
  64     $cust_location->set('censusyear', $current_year);
  65     $error = $cust_location->replace;
  66     $updated++;
  67   } # Else it's been updated since $date, so leave it alone.
  68   if ( $error ) {
  69     $dbh->rollback;
  70     die "error updating ".$cust_location->locationnum.": $error\n";
  71   }
  72 }
  73 warn "Queued $queued census code lookups, updated year in $updated records.\n";
  74 $dbh->commit;
  75
  76 sub usage {
  77     "Usage:\n\n  freeside-censustract-update [ -d date ] user\n\n"
  78   }
  79
  80 =head1 NAME
  81
  82 freeside-censustract-update - Update census tract codes to the current year.
  83
  84 =head1 SYNOPSIS
  85
  86   freeside-censustract-update [ -d date ] user
  87
  88 =head1 DESCRIPTION
  89
  90 Finds all customers whose census tract codes don't appear to be current
  91 and updates them to the current year.  The "current year" is 2020, unless the
  92 I<census_legacy> configuration variable is set.
  93
  94 The -d option tells the script to assume that tract codes last modified
  95 after some date are already current.  Those customers will just have
  96 their 'censusyear' field set to the current year.  For all other
  97 customers with non-current censusyear values, the current tract code
  98 will be looked up externally and stored in the censustract field.
  99
 100 The actual tract code lookup runs from the job queue, because it's slow.
 101 A separate job will be created for each customer.
 102
 103 =cut